Raster für Dialogentwürfe

Wie in Band 1 beschrieben ist es oft hilfreich, die Planung der Dialogoberfläche mit einem grafischen Entwurf zu visualisieren. Dazu eignen sich verschiedene Werkzeuge wie zum Beispiel das frei verfügbare Pencil Project. Um realistische und realisierbare Entwürfe erstellen zu können, benötigen Sie ein Bild der SAP GUI als Hintergrund, das zur Positionierung der Dialogelemente wahlweise mit einem Raster versehen ist. Hier finden Sie sowohl entsprechend vorbereitete Bilddateien als auch das in Band 1 beschriebene Skript, mit dem Sie das Raster selbst erzeugen können.
AuflösungBild ohne RasterBild mit Raster
1024x768Bild herunterladenBild herunterladen
1024x1024Bild herunterladenBild herunterladen
1024x2048Bild herunterladenBild herunterladen

Die folgende Windows-Kommandodatei erzeugt das Raster in der Grafikdatei. Sie benötigen dazu ImageMagick. Sichern Sie den folgenden Text in einer Datei mit der Endung .cmd im gleichen Verzeichnis wie die Grafikdateien und passen Sie die Parameter im ersten Teil des Skripts entsprechend Ihren Bedürfnissen an.

@ECHO OFF 
SETLOCAL EnableDelayedExpansion

REM Eingabe- und Ausgabedateiname
SET INFILE=Blanko-1024x768.png
SET OUTFILE=Raster-1024x768.png

REM Koordinaten des Rahmens (mit Bildverarbeitungsprogramm ausmessen)
SET TOP=226
SET LEFT=16
SET BOTTOM=700
SET RIGHT=1008

REM Anzahl der Zeilen und Spalten des Rahmens
SET COLUMNS=141
SET ROWS=23

REM Farbe der Hilfslinien als RGB-Angabe
SET COLOR=147,178,208

REM ==== ab hier sollten keine Änderungen mehr notwendig sein ===
SET /A DX=(%RIGHT%-%LEFT%)/%COLUMNS%
SET /A DY=(%BOTTOM%-%TOP%)/%ROWS%
ECHO Rastergroesse %DX%x%DY% Pixel
SET /A RRIGHT=%LEFT%+%COLUMNS%*%DX%
SET /A RBOTTOM=%TOP%+%ROWS%*%DY%
SET COMMANDS=
FOR /L %%X IN (%LEFT%,%DX%,%RRIGHT%) DO (
  SET COMMANDS=!COMMANDS! -draw "line %%X,%TOP% %%X,%RBOTTOM%"
)
FOR /L %%Y in (%TOP%,%DY%,%RBOTTOM%) DO (
  SET COMMANDS=!COMMANDS! -draw "line %LEFT%,%%Y %RRIGHT%,%%Y"
)
CONVERT.EXE %INFILE% -fill none -stroke rgb(%COLOR%) %COMMANDS% %OUTFILE%
German Doctors